transition Fade

[Flep]

I created a simple image gallery slideshow that demonstrates how to use the Fade class of Flash transitions.

The Fade class fades the movie clip object in or out. This effect requires no additional parameters.

I imported 12 images in the library of Flash, I assigned to each of them a class to "attack" from the library to the Stage with Actionscript.

Then, using a timer and classes TransitionManager and Fade, I created the image gallery.

The code I used:

package
{
	import flash.display.*;
	import flash.text.*;
	import flash.events.*;
	import flash.utils.*;
	import fl.transitions.*;
	import fl.transitions.easing.*
	
	public class Main extends MovieClip
	{
		private var image_classes:Array;
		
		private var timer:Timer;
		
		private var holder_mc:MovieClip;
		
		private const SPEED:int=3;
		
		private var boo:Boolean=true;
		
		private var id:int=0;
		
		public function Main()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(evt:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,init);
			
			image_classes=new Array("Caustic","Condensed","Dewdrop","Division","Frozen","Fusion",
									"FusionBlue","GoingUp","Jacks","Magma","Marine","Photosynthesis");
			
			createHolder();
			displayImage();
		}
		
		private function createHolder():void
		{
			holder_mc=new MovieClip();
			addChild(holder_mc);
		}
		
		private function displayImage():void
		{
			if(holder_mc.numChildren>0)
			{
				var bitmap:Bitmap=holder_mc.getChildAt(0) as Bitmap;
				holder_mc.removeChild(bitmap);
			}
			var image_class:Class=Class(getDefinitionByName(image_classes[id]));
			var imgData:BitmapData=new image_class(0,0);
			var img:Bitmap=new Bitmap(imgData);
			img.x=stage.stageWidth/2-img.width/2;
			img.y=stage.stageHeight/2-img.height/2;
			holder_mc.addChild(img);
			
			TransitionManager.start(holder_mc,{type:Fade, direction:Transition.IN,
			duration:1,easing:None.easeNone});
			startDisplayTimer();
		}
		
		private function hideImage(evt:TimerEvent):void
		{
			TransitionManager.start(holder_mc,{type:Fade, direction:Transition.OUT,
			duration:1,easing:None.easeNone});
			startHideTimer();
		}
		
		private function startDisplayTimer():void
		{
			if(timer!=null)
				timer.reset();
			timer=new Timer(SPEED*1000,1);
			timer.addEventListener(TimerEvent.TIMER,hideImage);
			timer.start();
		}
		
		private function startHideTimer():void
		{
			if(timer!=null)
				timer.reset();
			timer=new Timer(1000,1);
			timer.addEventListener(TimerEvent.TIMER,callDisplayImage);
			timer.start();
		}
		
		private function callDisplayImage(evt:TimerEvent):void
		{
			id++;
			if(id>image_classes.length-1)
				id=0;
			displayImage();
		}
	}
}

[victorcharles]

I don't see any "fade" effect in the example on this page- only the blinds transition.

[Flep]

fixed

[grigoriii]

hi,
how can I make this effect with my own photos.

[OrientExpress]

Hi,
change the photos in library with yours and be sure they have the same Class names in property panel of each photo.

[grigoriii]

hi,
thanks awfully for replay.

I have one more question. It is possibe to mix more transition effects on this images for examlpe: for each of this photos make a different transition effect (fade, iris, squezze, photo, wipe, etc.)

How make this effect, workable, and thanks a lot for replay.

[OrientExpress]

I will suggest your feedback to Flep

[ROBOTINAH]

Is theres away that i can add an url to this?