How to load a text file with Flash CS3

[Flep]

Wo wo wooo

Here we are with a new article to add to the series on how to load external files with Flash CS3.
We saw how to communicate with a PHP file   and how to integrate PHP and mySQL to Flash CS3
Now we will see how to load an external text file and display it in Flash CS3.
I would like to precise that this article is only educative and that I stick to the idea that to load external data, the best way is using an XML file.

Anyway…let us get into it… I create a FLA and save it as ‘file_di_testo.fla’.
I create a Document Class, an AS file saved as ‘Main.as’, implemented the following way:

package
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.IEventDispatcher;
	import flash.net.URLLoader;
	import flash.net.URLVariables;
	import flash.net.URLRequest;
	
	public class Main extends MovieClip
	{
		public function Main()
		{
			inviaDati();
		}
		
		private function addListeners(d:IEventDispatcher):void
		{
			d.addEventListener(Event.COMPLETE,completato);
		}
		
		private function completato(e:Event):void
		{
			var loader:URLLoader=URLLoader(e.target);
			var vars:URLVariables=new URLVariables(loader.data);
			trace(vars.nome);
		}
		
		private function inviaDati():void
		{
			var richiesta:URLRequest=new URLRequest();
			richiesta.url='http://www.flepstudio.org/swf/pippo.txt';
			var loader:URLLoader=new URLLoader();
			addListeners(loader);
			try 
			{
				loader.load(richiesta);
			} 
			catch (error:Error) 
			{
				trace('Non è stato possibile caricare il documento');
			}
		}
	}
}

The text file is named as ‘pippo.txt’, into which I have this simple declaration:
nome=filippo

Let us analyse the code

Constructor function
public function Main()
{
I call the method inviaDati();
inviaDati();
}

Methods
inviaDati();
I ask Flash to do an URL request using the URLRequest Class
var richiesta:URLRequest=new URLRequest();
I assign the path to the text file as the property of the URL request
richiesta.url='http://www.flepstudio.org/swf/pippo.txt';
I create an URLLoader
var loader:URLLoader=new URLLoader();
I call the method addListeners and load the text file using the method load of the Loader Class.
If the call to the file is incorrect, I do a trace which returns a message of error
addListeners(loader);
try
{
loader.load(richiesta);
}
catch (error:Error)
{
trace('Non è stato possibile caricare il documento');
}

addListeners();
I add a listener to follow the file’s loading phase. In this case, we only need it to know when the file has been loaded completely
d.addEventListener(Event.COMPLETE,completato);

completato();
I create a Loader to be able to retrieve the data from the uploaded file. In fact, I pass as a parameter the first URLLoader which has done the call
var loader:URLLoader=URLLoader(e.target);
I create an instance of the URLVariables Class to which I pass as parameter the data of the new URLLoader
var vars:URLVariables=new URLVariables(loader.data);
I retrieve the data, calling ‘nome’ (name of the variable included in the text file) as a property of URLVariables
trace(vars.nome);

Stay tuned !

[getosled]

Flep could you explain in a little more detail how to do this and possibly with out making a document class, im still learning and the document classes are still a bit confusing to me. All I want to do is leave a .txt document on my server and update that which should auto update my flash movie.

[Flep]

Hi

You need PHP to update the txt file.
Flash can't write files.

[getosled]

Flep,
ill physically go in and change the .txt file. I use to know how to do it under Flash 2.0

I just want CS3 to load the document in a dynamic text field. Ill change the document ever now and then.

[getosled]

I use to use a notepad file and loaded it into a dynamic text field, thats what i want to try to do again but in CS3 now.

[Flep]

Hi,
without Document Class:

loadFile();

function loadFile():void
{
	var request:URLRequest=new URLRequest();
	request.url='http://www.flepstudio.org/swf/pippo.txt';
	var loader:URLLoader=new URLLoader();
	addListeners(loader);
	try 
	{
		loader.load(request);
	} 
	catch (error:Error) 
	{
		trace('Non è stato possibile caricare il documento');
	}
}

function addListeners(d:IEventDispatcher):void
{
	d.addEventListener(Event.COMPLETE,onComplete);
}
		
function onComplete(e:Event):void
{
	var loader:URLLoader=URLLoader(e.target);
	var vars:URLVariables=new URLVariables(loader.data);
	trace(vars.nome);
}

[getosled]

You are the man Flep.. Is there any guide to learning about document classes? I notice alot of flash is done with a document class, but im having a hard time with AS 3.0 as it is much less trying to learn how to do a document class.

[Flep]

Originally Posted by getosled

You are the man Flep.. Is there any guide to learning about document classes? I notice alot of flash is done with a document class, but im having a hard time with AS 3.0 as it is much less trying to learn how to do a document class.

1)
The Document Class of Flash CS3

2)
Call from the timeline to the Document Class and vice versa with Flash CS3

3)
http://www.flepstudio.org/forum/obje...ing-tutorials/

[JAYCO]

This looks good.

However, instead of trace the contents of the text file, i want to dispay it into a textfield or a text area. What additional programming is necessary?

Thank You

[Flep]

Hi JAYCO and welcome

You just need to add the value at a TextField.
my_txt.text=vars.nome;