Simple Email Form Problem

[chosendesigns]

Hi.. I currently have this written in my flash page for an email form linking to an external php form. It should be that when you click the submit button (submit) the email.php script is run and it goes to page 2 of my flash site giving a confirmation message.

Here is my flash code:

PHP Code:

submit.addEventListener(MouseEvent.CLICK,function():void {

var emailform:URLRequest = new URLRequest();
emailform.url = "email.php";
gotoAndStop(2);
}
);


Ive tried my php script with a standard html form and it works just fine so my php code works its just I dont understand how to link php to flash properly.

[tem]

Hi!
you need to use a method like this one:

private function inviaDati():void
		{
			var variables:URLVariables=new URLVariables();
                        //here I set the variables to send to the php
			variables.fieldOne=my_var1;
			variables.fieldTwo=my_var2;
			variables.fieldThree=my_var3;
			var richiesta:URLRequest=new URLRequest();
			//cambia l'url del file php in base a dove lo metti  :))
			richiesta.url='http://www.miosito.com/mioFile.php';
			richiesta.method=URLRequestMethod.POST;
			richiesta.data=variables;
			var loader:URLLoader=new URLLoader();
			loader.dataFormat=URLLoaderDataFormat.VARIABLES;
			addListeners(loader);
			try 
			{
				loader.load(richiesta);
			} 
			catch (error:Error) 
			{
				trace('Unable to load requested document.');
			}
		}
		
		private function addListeners(d:IEventDispatcher):void
		{
			d.addEventListener(Event.OPEN,inizio);
			d.addEventListener(ProgressEvent.PROGRESS,inProgresso);
			d.addEventListener(Event.COMPLETE,completato);
			d.addEventListener(SecurityErrorEvent.SECURITY_ERROR,securityError);
			d.addEventListener(HTTPStatusEvent.HTTP_STATUS,httpStatus);
			d.addEventListener(IOErrorEvent.IO_ERROR,ioError);
		}
		
		private function inizio(e:Event):void 
		{
			debug_txt.text='Connecting to the server...';
		}
		
		private function inProgresso(e:ProgressEvent):void 
		{
			debug_txt.text='Sending...';
		}
		//if the php file sends back an echo "answer=ok";
		private function completato(e:Event):void
		{
			var loader:URLLoader=URLLoader(e.target);
			var vars:URLVariables=new URLVariables(loader.data);
			if(vars.answer=='ok')
				debug_txt.text='Thank you the message has been sent';
			else
				debug_txt.text='Sistem Error please try again';
			
		}