Flash PHP Controllo $_SERVER[requestmethod] = POST

[NikiNiki]

myButton.addEventListener(MouseEvent.CLICK, myButtonFunction);

function myButtonFunction(event: MouseEvent):void
{
var request:URLRequest = new URLRequest("http://localhost/xphil/modnews.php");
request.method = URLRequestMethod.POST;
navigateToURL(request,"_self");
}

Ho creato un pulsante aggiungendovi questo codice, ma alla pagina modnews, effettuo un controllo $_SERVER['REQUEST_METHOD'] == 'POST'.

Ed ogni volta mi dice che il metodo di richiesta della pagina è GET e non POST.

Aiutatemi!! Non capisco dove sbaglio!

Grazie

[tem]

Ciao!
per passare i dati in post puoi utilizzare questo metodo.. è tratto da un form mail di Flep:

private function inviaDati():void
		{
                        //in questo caso inviamo al php delle variabili
			var variables:URLVariables=new URLVariables();
			variables.email=email_txt.text;
			variables.messaggio=message_txt.text;
			variables.titolo=title_txt.text;
			variables.nome=name_txt.text;
			var richiesta:URLRequest=new URLRequest();
			//la nostra richiesta viene fatta a questo file
			richiesta.url='http://www.flepstudio.org/utilita/emailForm/inviaMail.php';
			richiesta.method=URLRequestMethod.POST;
			richiesta.data=variables;
			var loader:URLLoader=new URLLoader();
			loader.dataFormat=URLLoaderDataFormat.VARIABLES;
			addListeners(loader);
			try 
			{
				loader.load(richiesta);
			} 
			catch (error:Error) 
			{
				trace('Unable to load richiestaed document.');
			}
		}
		
		private function addListeners(d:IEventDispatcher):void
		{
			d.addEventListener(Event.OPEN,inizio);
			d.addEventListener(ProgressEvent.PROGRESS,inProgresso);
			d.addEventListener(Event.COMPLETE,completato);
			d.addEventListener(SecurityErrorEvent.SECURITY_ERROR,securityError);
			d.addEventListener(HTTPStatusEvent.HTTP_STATUS,httpStatus);
			d.addEventListener(IOErrorEvent.IO_ERROR,ioError);
		}
		
		private function inizio(e:Event):void 
		{
			debug_txt.text='Invio messaggio in corso...';
		}
		
		private function inProgresso(e:ProgressEvent):void 
		{
			debug_txt.text='Invio messaggio in corso...';
		}
		
                //controllo la risposta dal php
		private function completato(e:Event):void
		{
			var loader:URLLoader=URLLoader(e.target);
			var vars:URLVariables=new URLVariables(loader.data);
                         //qui controllo se ricevo l'echo answer="ok" dal php.
			if(vars.answer=='ok')
				debug_txt.text='The message has been correctly sent';
			else
				debug_txt.text='System error, please try again';
			togliAlert();
		}
		
		private function securityError(e:SecurityErrorEvent):void 
		{
			debug_txt.text='Errore di sistema, ripova per favore';
		}
		
		private function httpStatus(e:HTTPStatusEvent):void {}
		
		private function ioError(e:IOErrorEvent):void 
		{
			debug_txt.text='Errore di sistema, ripova per favore';
		}

spero possa aiutarti..

[NikiNiki]

Il mio problema non è passare dei dati tramite post, ma sono controllare che la richiesta alla pagina avvenga tramite POST, poichè devo eseguire una visualizzazione della stessa in base al fatto che essa venga chiamata tramite POST o tramite GET.

E' solo che se faccio un controllo PHP $_SERVER[REQUEST_METHOD] == 'POST'
lui mi dice che la richiesta è sempre get anche se il pulsante ha
request.method = URLRequestMethod.POST;

[tem]

Ciao!
credo che allora dovresti utilizzare questo metodo: AS3 Posting Variables to a Page | Wookets Wove

var request:URLRequest = new URLRequest("http://yourserver.com/files/download/");
request.method = URLRequestMethod.POST;
var variables:URLVariables = new URLVariables();
variables.resourceType = "Document";
variables.resourceId = 34bds34pkd;
request.data = variables;
navigateToURL(request, "_blank");

fai una prova inviando delle variabili.. forse nel tuo caso facendo una richiesta post senza inviare variabili veniva interpretato come un get dal php...

[NikiNiki]

Grazie!!
Ora funziona, anche se non capisco perchè uno deve essere costretto a passare delle variabili per utilizzare il metodo post.

Grazie ancora

Ciaoo