transizione Wipe

[Flep]

Ho creato una semplice galleria immagini slideshow che dimostra come utilizzare la classe Wipe delle transitions di Flash.

La classe Wipe mostra o nasconde l'oggetto utilizzando una maschera animata di una forma che si muove orizzontalmente.

Questo effetto richiede il seguente parametro:

startPoint: Un numero intero che indica la posizione di partenza; il range è tra 1 e 9:

1. In alto a sinistra


2. In alto al centro


3. In alto a destra


4. A sinistra al centro


5. Al centro


6. A destra al centro


7. In basso a sinistra


8. In basso al centro


9. In basso a destra

Ho importato 12 immagini nella libreria di Flash, ho assegnato ad ognuna di loro una classe per "attaccarle" dalla libreria allo stage con Actionscript.

Poi, tramite un timer e le classi TransitionManager e Wipe ho creato la galleria immagini.

Ecco il codice che ho usato:

package
{
	import flash.display.*;
	import flash.text.*;
	import flash.events.*;
	import flash.utils.*;
	import fl.transitions.*;
	import fl.transitions.easing.*
	
	public class Main extends MovieClip
	{
		private var image_classes:Array;
		
		private var timer:Timer;
		
		private var holder_mc:MovieClip;
		
		private const SPEED:int=3;
		
		private var boo:Boolean=true;
		
		private var id:int=0;
		
		public function Main()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(evt:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,init);
			
			image_classes=new Array("Caustic","Condensed","Dewdrop","Division","Frozen","Fusion",
									"FusionBlue","GoingUp","Jacks","Magma","Marine","Photosynthesis");
			
			createHolder();
			displayImage();
		}
		
		private function createHolder():void
		{
			holder_mc=new MovieClip();
			addChild(holder_mc);
		}
		
		private function displayImage():void
		{
			if(holder_mc.numChildren>0)
			{
				var bitmap:Bitmap=holder_mc.getChildAt(0) as Bitmap;
				holder_mc.removeChild(bitmap);
			}
			var image_class:Class=Class(getDefinitionByName(image_classes[id]));
			var imgData:BitmapData=new image_class(0,0);
			var img:Bitmap=new Bitmap(imgData);
			img.x=stage.stageWidth/2-img.width/2;
			img.y=stage.stageHeight/2-img.height/2;
			holder_mc.addChild(img);
			
			TransitionManager.start(holder_mc,{type:Wipe,direction:Transition.IN,
			duration:1,easing:None.easeNone,startPoint:1});
			startDisplayTimer();
		}
		
		private function hideImage(evt:TimerEvent):void
		{
			TransitionManager.start(holder_mc,{type:Wipe,direction:Transition.OUT,
			duration:1,easing:None.easeNone,startPoint:1});
			startHideTimer();
		}
		
		private function startDisplayTimer():void
		{
			if(timer!=null)
				timer.reset();
			timer=new Timer(SPEED*1000,1);
			timer.addEventListener(TimerEvent.TIMER,hideImage);
			timer.start();
		}
		
		private function startHideTimer():void
		{
			if(timer!=null)
				timer.reset();
			timer=new Timer(1000,1);
			timer.addEventListener(TimerEvent.TIMER,callDisplayImage);
			timer.start();
		}
		
		private function callDisplayImage(evt:TimerEvent):void
		{
			id++;
			if(id>image_classes.length-1)
				id=0;
			displayImage();
		}
	}
}

[shain]

ragazzi non riesco a capire pechè il file in allegato.zip non riesco ad aprirlo... mi dice non supportato... mi aiutate per favore! grazie

[OrientExpress]

Ciao shain e benvenuto
Ti serve almeno la versione CS3 di Flash.

[shain]

Ciao OrientExpress, grazie per l'info... tutto risolto. Grazie Ancora!