Incapsulamento e metodi Getter & Setter

[Flep]

Citando Actionscript 3.0 e quindi la Programmazione Orientata agli Oggetti, non posso e non voglio 'bypassare' l'incapsulamento ed i metodi Getter & Setter. L'incapsulamento è una tecnica per proteggere/nascondere le proprietà della nostra Classe. Questo perchè, potremmo trovarci nella situazione di dover creare una Classe per poi consegnarla ad un cliente o un designer ma non vogliamo che abbiano accesso diretto alle proprietà della nostra classe. Per chi si affaccia ora alla programmazione potrebbe apparire complesso, ma vedremo di smentire questa sensazione. Mi spiego meglio,
abbiamo visto come definire delle proprietà nelle nostre classi:

package
{	import flash.display.MovieClip;

	public class Filippo extends MovieClip	
	{		
		private var mano:MovieClip;		
		private var misura:Number;		
		
		public function Filippo()		
		{
			
		}	
	}
}

Nella classe Filippo, mani e misura sono 2 proprietà. Fino ad ora abbiamo accesso alle proprietà nel modo più comune, vale a dire direttamente:

package
{	
	import flash.display.MovieClip;	
	import flash.display.Shape;		
	
	public class Filippo extends MovieClip	
	{		
		private var mano:Shape;		
		private var misura:Number=100;	
		
		public function Filippo()		
		{                       
			misura=400;			
			mano=new Shape();			
			mano.graphics.beginFill(0xFFCC00);			
			mano.graphics.drawRect(0,0,misura,misura);			
			mano.graphics.endFill();			
			addChild(mano);		
		}	
	}
}

Se noi istanziassimo la classe dalla Timeline in questo modo:
var filo:Filippo=new Filippo();
per poter dare accesso alla proprietà mano, dovremmo cambiarne la sua definizione da private a public e non è buona norma.
Se volessimo che chi usa la classe acceda alle proprietà ma non direttamente (in quanto private) dobbiamo definire dei metodi che restituiscono quelle proprietà. Eccoci al punto, abbiamo 2 modi:

package
{	
	import flash.display.MovieClip;	
	import flash.display.Shape;		
	
	public class Filippo extends MovieClip	
	{		
		private var mano:Shape;		
		private var misura:Number=100;	
		
		public function Filippo()		
		{			
			mano=new Shape();			
			mano.graphics.beginFill(0xFFCC00);			
			mano.graphics.drawRect(0,0,misura,misura);			
			mano.graphics.endFill();			
			addChild(mano);		
		}				
		
		public function dammiLaMisura():Number		
		{			
			return misura;		
		}		
		
		public function tieniLaMisura(n:Number):void		
		{			
			misura=n;		
		}	
	}
}

in questo caso accederemmo alla proprietà misura dalla Timeline in questo modo:
var filippo:Filippo=new Filippo();
filippo.tieniLaMisura(400);
trace(filippo.dammiLaMisura());

oppure i Setter & Getter:

package
{
	import flash.display.MovieClip;
	import flash.display.Shape;
	
	public class Filippo extends MovieClip
	{
		private var mano:Shape;
		private var _misura:Number=100;
		
		public function Filippo()
		{
			mano=new Shape();
			mano.graphics.beginFill(0xFFCC00);
			mano.graphics.drawRect(0,0,misura,misura);
			mano.graphics.endFill();
			addChild(mano);
		}
		
		public function set misura(n:Number):void
		{
			_misura=n;
		}
		public function get misura():Number
		{
			return _misura;
		}
	}
}

in questo caso accederemmo alla proprietà misura in questo modo:
var filippo:Filippo=new Filippo();
filippo.misura=400;
trace(filippo.misura);

In entrambi i casi abbiamo implementato dei metodi pubblici per assegnare o ricevere un valore delle proprietà private.
Alcuni programmatori ( tra cui il sottoscritto :P )considerano il primo esempio troppo scomodo, in quanto è più semplice :
filo.misura=400; (getter&setter)
invece di
filo.tieniLaMisura(400);

Stay tuned !

[foriddo]

Ciao Flep....non posso che farti i complimenti per questa splendida guida che permette anche a me che non sono un grande programmatore di seguire le lezioni con abbastanza facilità.

Per la lezione in questione "Incapsulamento e metodi Getter & Setter" ho fatto tutto alla lettera ma mi da errore nel file swf. L'errore è questo:

Error: Error #2136: Il file SWF file:///G|/lavori/corso%5Fas3/sesta.swf contiene dati non validi.
at Sesta/::frame15()

Il codice che ho inserito nel frame 15 è questo:
var sesta:Sesta=new Sesta();
sesta.misura=150;
trace(sesta.misura);


Cosa sbaglio?
Grazie

[Flep]

E' strano quell' errore...
per caso muovi la timeline principale ?
Mi faresti vedere l' intera classe ?

[foriddo]

Originally Posted by Flep

E' strano quell' errore...
per caso muovi la timeline principale ?
Mi faresti vedere l' intera classe ?

La mia classe è la seguente:
package
{
import flash.display.MovieClip;
import flash.display.Shape;

public class Sesta extends MovieClip
{
private var mano:Shape;
private var _misura:Number=300;

public function Sesta()
{
mano=new Shape();
mano.graphics.beginFill(0xFFCC00);
mano.graphics.drawRect(0,0,misura,misura);
mano.graphics.endFill();
addChild(mano);


}
public function set misura(n:Number):void
{
_misura=n;
}
public function get misura():Number
{
return _misura;
}
}
}

Nel primo frame del sesta.fla:
var sesta:Sesta=new Sesta();
sesta.misura=150;
trace(sesta.misura);

[Flep]

Il codice è tutto corretto.
Hai detto che istanzi la classe Sesta dal frame1, ma la timeline si muove ? Nel senso c'è uo stop nel frame 1 oppure no ?

[foriddo]

Mi da lo stesso errore sia che metto lo stop(); sia che non lo metto nel frame 1...

[Flep]

Aspetta, ho notato adesso.
Togli extends MovieClip.

[foriddo]

ho tolto extends MovieClip

ora mi tira fuori i seguenti errori:
1180: Chiamata al metodo non definito addFrameScript.
1180: Chiamata al metodo non definito addChild.
5000: La classe 'Sesta' deve essere una sottoclasse di 'flash.display.MovieClip' perché è collegata a un simbolo di libreria di quel tipo.

[Flep]

Se è collegata ad un simbolo in libreria allora deve estendere per forza MovieClip.
Quindi rimettilo e facciamo un passo indietro.
Non ho ancora provato a utilizzare getter&setter in una classe linkata ad una MovieClip in libreria.

Non so se è possibile.
Prova a dichiarare la classe così:
public dynamic class Sesta extends MovieClip

[foriddo]

sempre lo stesso errore...
se c'è un modo ti invio il .fla e il .as non voglio farti perdere ulteriore tempo