Flash CS3 - Flash CS4

valesan · #1 (**permalink**) 02-11-07, 08:33

Innanzi tutto un saluto a tutti,

sono nuovo quì ma soprattutto sono nuovo nel mondo del flash ...
ho letto molto, ed ho trovato Header rotante free che sembra faccia proprio al mio caso ...
l'unica cosa che vorrei sapere è se è possibile fare in modo che non ruoti all'inifnito ma si fermi all'ultima immagine lasciandola statica !?!?!?

grazie mille e complimenti ...

Valerio

Flep · #2 (**permalink**) 02-11-07, 08:48

Ciao valesan e benvenuto

Certo che è possibile, il file Main.as diventa così:

Code:

/*
 *************************************
 * Header                            
 * http://www.FlepStudio.org         
 * © Author: Filippo Lughi          
 * version 1.0                      
 *************************************
 */
package
{
	import flash.display.MovieClip;
	import flash.display.BitmapData;
	import flash.display.Bitmap;
	import flash.geom.Point;
	import flash.utils.Timer;
	import flash.events.Event;
	import flash.events.TimerEvent;
	import flash.events.ContextMenuEvent;
	import flash.ui.ContextMenu;
	import flash.ui.ContextMenuItem;
	import flash.net.URLRequest;
	import flash.net.navigateToURL;
	import flash.events.MouseEvent;
	
	public class Main extends MovieClip
	{
		private var clips_array:Array;
		private var masks_array:Array;
		private var points_array:Array;
		private var url_array:Array=new Array("http://www.flepstudio.org1/","http://www.flepstudio.org2/","http://www.flepstudio.org3/",
																			"http://www.flepstudio.org4/","http://www.flepstudio.org5/");
		
		private var bit_data:BitmapData;
		
		private var clip_mc:MovieClip;
		private var mask_mc:MovieClip;
		
		private var counter:int=0;
		private var numeroMaschere:int=10;
		
		private var timer:Timer;
		
		public function Main()
		{
			initMenu();
			init();
			contaImmagini();
			initBitmap();
			initPoints();
			initMask();
			fadeMask();
		}
		
		private function init():void
		{
			stage.frameRate=31;
			
			clips_array=new Array();
			points_array=new Array();
		}
		
		private function contaImmagini():void
		{
			var point:Point=new Point(stage.stageWidth/2,stage.stageHeight/2);
			var objects:Array=this.getObjectsUnderPoint(point); 
			for(var i:int=0;i<objects.length;i++)
			{
				clips_array.push(objects[i].parent);
				clips_array[i].id=i;
				clips_array[i].buttonMode=true;
				clips_array[i].addEventListener(MouseEvent.MOUSE_DOWN,go);
			}
		}
		
		private function go(evt:Event):void
		{
			var request:URLRequest=new URLRequest();
			request.url=url_array[evt.currentTarget.id];
			navigateToURL(request,"_self");
		}
		
		private function initBitmap():void
		{
			for(var i:int=0;i<clips_array.length;i++)
			{
				clips_array[i].visible=false;
				if(i==counter)
					clips_array[i].visible=true;
				else if(i==counter-1)
					clips_array[i].visible=true;
			}
			if(counter==0)
				clips_array[clips_array.length-1].visible=true;
			mask_mc=new MovieClip();
			this.addChild(mask_mc);
			swapChildren(clips_array[counter],mask_mc);
			clips_array[counter].mask=mask_mc;
		}
		
		private function initPoints():void
		{
			var boo:Boolean=true;
			var doppio:int=numeroMaschere*2;
			var w:Number=Math.floor(clips_array[0].width/doppio);
			var h:Number=Math.floor(clips_array[0].height/numeroMaschere);
			
			for(var i:int=0;i<doppio;i++)
			{
				for(var j:int=0;j<numeroMaschere;j++)
				{
					if(!boo)
					{
						var point:Point;
						point=new Point(clips_array[0].x+w*i,clips_array[0].y+h*(numeroMaschere-1-j));
						points_array.push(point);
					}
					else
					{
						var point2:Point;
						point2=new Point(clips_array[0].x+w*i,clips_array[0].y+h*j);
						points_array.push(point2);
					}
				}
				boo=!boo;
			}
		}
		
		private function initMask():void
		{
			masks_array=new Array();
			var doppio:int=numeroMaschere*2;
			var w:Number=clips_array[0].width/doppio;
			var h:Number=clips_array[0].height/numeroMaschere;
			
			for(var k:int=0;k<points_array.length;k++)
			{
				var clip:MovieClip=new MovieClip();
				clip.graphics.beginFill(0x66FF00,1);
				clip.graphics.moveTo(0,0);
				clip.graphics.lineTo(-w/2,-h/2);
				clip.graphics.lineTo(w/2,-h/2);
				clip.graphics.lineTo(w/2,h/2);
				clip.graphics.lineTo(-w/2,h/2);
				clip.graphics.lineTo(-w/2,-h/2);
				clip.graphics.endFill();
				clip.scaleX=0;
				clip.scaleY=0;
				masks_array.push(clip);
			}
			for(var s:int=0;s<masks_array.length;s++)
			{
				masks_array[s].x=points_array[s].x+w/2;
				masks_array[s].y=points_array[s].y+h/2;
				mask_mc.addChild(masks_array[s]);
			}
		}
		
		private function fadeMask():void
		{
			timer=new Timer(10,masks_array.length);
			timer.addEventListener(TimerEvent.TIMER,go);
			timer.addEventListener(TimerEvent.TIMER_COMPLETE,stopp);
			timer.start();
			function go(t:TimerEvent):void
			{
				masks_array[timer.currentCount-1].addEventListener(Event.ENTER_FRAME,expandMask);
			}
			function stopp(t:TimerEvent):void
			{
				// ****IMPOSTARE LA VELOCITA ( non meno di 2000 )*****
				/**/timer=new Timer(2000,1);                      /**/
				//**************************************************//
				timer.addEventListener(TimerEvent.TIMER,avanza);
				timer.start();
			}
		}
		
		private function expandMask(e:Event):void
		{
			e.target.arrX=1;
			var dx:Number=e.target.arrX-e.target.scaleX;
			var ax:Number=dx*.15;
			e.target.scaleX+=ax;
			e.target.scaleY+=ax;
			if(Math.abs(dx)<=.03)
			{
				e.target.scaleX=e.target.arrX;
				e.target.scaleY=e.target.arrX;
				e.target.removeEventListener(Event.ENTER_FRAME,expandMask);
			}
		}
		
		private function avanza(t:TimerEvent):void
		{
			counter++;
			if(counter>=clips_array.length)
				counter=0;
			else
			{
				clips_array[counter].mask=null;
				removeChild(mask_mc);
				initBitmap();
				initMask();
				fadeMask();
			}
		}
		
		// NON rimuovere per favore !
		public function initMenu():void
		{
			var etichetta:String="© FlepStudio.org";
			var cm:ContextMenu=new ContextMenu();
			var item:ContextMenuItem=new ContextMenuItem(etichetta);
			cm.hideBuiltInItems();
			cm.customItems.push(item);
			item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT,itemHandler1);
			this.contextMenu=cm;
		}
		private function itemHandler1(event:ContextMenuEvent):void
		{
			var url:String="http://www.flepstudio.org/";
			var request:URLRequest=new URLRequest(url);
			navigateToURL(request,"_parent");
		}
	}
}

valesan · #3 (**permalink**) 02-11-07, 10:46

ti ringrazio infinitamente...
mi puoi sottolineare cosa hai cambiato nel codice per far fermare il loop ;)

e ancora ... è possibile usare il preloader per caricare questo header rotante ?

grazie

valesan · #4 (**permalink**) 02-11-07, 10:48

ho provato da solo a caricare l'header con il preloader per principianti ma mi da questo errore :

TypeError: Error #1009: Impossibile accedere a una proprietà o a un metodo di un riferimento oggetto null.
at Main/::init()
at Main$iinit()

cosa posso fare ?

Flep · #5 (**permalink**) 02-11-07, 11:04

Quote:

Originally Posted by valesan

ti ringrazio infinitamente...
mi puoi sottolineare cosa hai cambiato nel codice per far fermare il loop ;)

e ancora ... è possibile usare il preloader per caricare questo header rotante ?

grazie

Avevo cambiato la funzione avanza in questo modo:

Code:

private function avanza(t:TimerEvent):void
		{
			counter++;
			if(counter>=clips_array.length)
				counter=0;
			else
			{
				clips_array[counter].mask=null;
				removeChild(mask_mc);
				initBitmap();
				initMask();
				fadeMask();
			}
		}

Se vuoi provare a caricarlo col preloader allora prova a tenere la funzione Main() e la funzione init() in questo modo:

Code:

public function Main()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(evt:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,init);
			stage.frameRate=31;
			
			clips_array=new Array();
			points_array=new Array();
			
			initMenu();
			contaImmagini();
			initBitmap();
			initPoints();
			initMask();
			fadeMask();
		}

Ripubblica l' SWF e poi riprova a caricarlo col preloader.

valesan · #6 (**permalink**) 02-11-07, 11:23

gentilissimo e rapidissimo ...
ora è tutto ok !!

mauromo69 · #7 (**permalink**) 21-12-07, 06:52

Innanzitutto mi presento, sono Mauro e colgo l'occasione per farvi gli Auguri di Buon Natale.
Principiante di Flash ho il medesimo problema riscontrato da valesan pur modificando la DC Main dell'header come suggerito da Flep.

Quote:

TypeError: Error #1010: Un termine risulta undefined e non ha proprietà.
at Main/initBitmap()
at Main/init()

Sto cercandi di caricare l'swf nella mia pagina principale del sito dentro una funzione che chiude un'animazione precedente senza preloader

Quote:

package
{
import flash.display.MovieClip;
import flash.display.SimpleButton;
import flash.net.URLRequest;
import flash.net.navigateToURL;
import flash.events.*;
import flash.display.Loader;

public class Home extends MovieClip
{
public function Home()
{
Cont();
}
public function Cont():void
{
var url:String='main.swf';
var request:URLRequest=new URLRequest(url);
var lo:Loader=new Loader();
lo.load(request);
addChild(lo);

}
}
}

non sono tutte le funzioni presenti ma ' l'estratto della mia DC del swf principale.
provando a caricare altri swf (per provare che il loader funzionasse a dovere) ho riscontrato il medesimo problema per il Contatore e il Guestbook mentre per il Form Email nessun problema. Si può fare niente? Grazie per l'attenzione.
Complimenti per il forum davvero illuminante senza di voi non sarei neanche riuscito a fare una piccola animazione mentre ora, piano piano mi sto cimentando con l'Actonscript. Grazie anche per questo. Mauro

Flep · #8 (**permalink**) 21-12-07, 07:06

Ciao Mauro e benvenuto

Un Buon Natale anche a te !

Credo che il tuo problema sia che fai addChild(lo); subito e non quando l' SWF è stato caricato.

Dichiara la variabile lo di tipo Loader nelle proprietà della classe e non dentro la funzione Cont.
Poi nella funzione Cont, aggiungi un listener:
lo.contentInfoLoader.addEventListener(Event.COMPLE TE,finito);
lo.load(request);

e dentro la funzione finito, fai l' addChild di lo:
function finito(evt:Event):void
{
addChild(lo);
}

mauromo69 · #9 (**permalink**) 21-12-07, 08:17

Grazie per la solerte risposta, ho fatto come mi hai suggerito ma il mio problema purtroppo rimane

Quote:

package
{
import flash.display.MovieClip;
import flash.display.SimpleButton;
import flash.net.URLRequest;
import flash.net.navigateToURL;
import flash.events.*;
import flash.display.Loader;
import flash.display.LoaderInfo; <-- aggiunta

public class Home extends MovieClip
{
private var lo:Loder;

public function Home()
{
Cont();
}
public function Cont():void
{
var url:String='main.swf';
var request:URLRequest=new URLRequest(url);
lo=new Loader();
lo.contentLoaderInfo.addEventListener(Event.COMPLE TE,finito);
/ ho messo contentLoaderInfo perchè mi dava errore/
lo.load(request);
}
function finito(evt:Event):void
{
addChild(lo);
}
}
}

con il seguente errore

Quote:

TypeError: Error #1010: Un termine risulta undefined e non ha proprietà.
at Main/initBitmap()
at Main/init()
at flash.display::DisplayObjectContainer/addChild()
at Home/finito()

non so se manca qualche impostazione particolare del programma... sono ancora in fase di studio. grazie ancora Mauro

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Header Rotante	Flep	Utilità di FlepStudio	76	27-11-08 14:39
Header rotante 2	Flep	Utilità di FlepStudio	77	11-11-08 17:14
Header rotante 2	woody	AIUTO utilità free	2	19-09-08 12:48
Header Rotante 2	sharemind	AIUTO utilità free	3	01-04-08 10:55
header rotante	maurizio	AIUTO utilità free	2	18-10-07 11:12

Flash CS3 - Flash CS4

Ancora Header rotante

Ancora Header rotante

Similar Threads