Mini-gallery-3 modifiche?

[Onsitus]

Buongiorno a tutti,:)

sto provando a modifichare la mini galleria.
1. i thumbs in bianco/nero che si convertono in colore sul rollover
2. il primo e ultimo thumb on rollover surpassano l'altezza della foto ingrandita. Quella foto sarebbe la mia altezza massimale. Se limito il filmato a quelle misure gli 2 thumbs vengono tagliate
3. una volta che un thumb e selezionato, potrebbe rimanere 'allargato' mentre si visualizza la sua imagine?
:confused:

Grazie in anticipo per qualunque aiuto/consigli.
ciauz

[Flep]

Ciao Gaelle :)

1. Non credo sia possibile con quello script, bisognerebbe rifare quasi tutto
2. Hai provato a rimpicciolire le immagini delle thumbs ?
3. Puoi sistemare con questa nuova Main.as:

 package
{
    import flash.display.MovieClip;
    import flash.filters.ColorMatrixFilter;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import fl.transitions.*;
    import fl.transitions.easing.Regular;
    import flash.events.ContextMenuEvent;
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.net.URLRequest;
    import flash.net.navigateToURL;
    
    public class Main extends MovieClip
    {
        private var holders_array:Array;
        private var thumbs_array:Array;
        private var masks_array:Array;
        private var filters_array:Array;
        private var pics_array:Array;
        
        private var ColorMatrix:ColorMatrixFilter;
        
        private var currentPic:int=0;

        public function Main()
        {
            init();
        }
        
        private function init():void
        {
            stage.frameRate=31;
            
            initMenu();
            
            holders_array=new Array(holder_mc.holder_pic_0_mc,
                                holder_mc.holder_pic_1_mc,
                                holder_mc.holder_pic_2_mc,
                                holder_mc.holder_pic_3_mc,
                                holder_mc.holder_pic_4_mc,
                                holder_mc.holder_pic_5_mc,
                                holder_mc.holder_pic_6_mc);
            
            thumbs_array=new Array(holder_mc.holder_pic_0_mc.thumb_0_mc,
                                holder_mc.holder_pic_1_mc.thumb_1_mc,
                                holder_mc.holder_pic_2_mc.thumb_2_mc,
                                holder_mc.holder_pic_3_mc.thumb_3_mc,
                                holder_mc.holder_pic_4_mc.thumb_4_mc,
                                holder_mc.holder_pic_5_mc.thumb_5_mc,
                                holder_mc.holder_pic_6_mc.thumb_6_mc);
            
            pics_array=new Array(pic_0_mc,pic_1_mc,pic_2_mc,pic_3_mc,pic_4_mc,pic_5_mc,pic_6_mc);
            
            masks_array=new Array();
            
            filters_array=new Array(1,0,0,0,-50,0,1,0,0,-50,0,0,1,0,-50,0,0,0,1,0);
            
            ColorMatrix=new ColorMatrixFilter(filters_array);
            
            positionthumbs_array();
            createmasks_array();
            addListeners();
            
            TransitionManager.start(pics_array[0],{type:Photo,direction:Transition.IN,
                                            duration:.5,easing:Regular.easeOut});
        }
        
        private function positionthumbs_array():void
        {
            for(var i:int=0;i<holders_array.length;i++)
            {
                pics_array[i].visible=false;
                holders_array[i].y=thumbs_array[0].height/2*i;
                thumbs_array[i].filters=[ColorMatrix];
                thumbs_array[i].isPressed=false;
                thumbs_array[i].mouseChildren=false;
            }
            holder_mc.y=(stage.stageHeight-holder_mc.height)/2;
        }
        
        private function createmasks_array():void
        {
            for(var i:int=0;i<holders_array.length;i++)
            {
                var masking:MovieClip=new MovieClip();
                masking.graphics.beginFill(0x66FF00,1);
                masking.graphics.drawRect(-30,-15,60,30);
                
                masking.id=i;
                holders_array[i].id=i;
                thumbs_array[i].id=i;
                holders_array[i].buttonMode=true;
                
                masking.x=thumbs_array[i].x+thumbs_array[i].width/2;
                masking.y=thumbs_array[i].y+thumbs_array[i].height/2;
                holders_array[i].addChild(masking);
                thumbs_array[i].mask=masking;
                masks_array.push(masking);
            }
        }
        
        private function addListeners():void
        {
            for(var i:int=0;i<holders_array.length;i++)
            {
                holders_array[i].addEventListener(MouseEvent.MOUSE_OVER,mouseIsOver);
                holders_array[i].addEventListener(MouseEvent.MOUSE_OUT,mouseIsOut);
                holders_array[i].addEventListener(MouseEvent.MOUSE_DOWN,showPicture);
            }
        }
        
        private function mouseIsOver(m:MouseEvent):void
        {
            m.currentTarget.isPressed=false;
            m.currentTarget.removeEventListener(Event.ENTER_FRAME,scaleDown);
            m.currentTarget.addEventListener(Event.ENTER_FRAME,liftUp);
        }
        
        private function mouseIsOut(m:MouseEvent):void
        {
            m.currentTarget.removeEventListener(Event.ENTER_FRAME,liftUp);
            if(!m.currentTarget.isPressed)
                m.currentTarget.addEventListener(Event.ENTER_FRAME,scaleDown);
        }
        
        private function closing(m:MovieClip):void
        {
            m.addEventListener(Event.ENTER_FRAME,scaleDown);
        }
        
        private function liftUp(e:Event):void
        {
            var n:int=50;
            var newFilters:Array=new Array(1,0,0,0,n,0,1,0,0,n,0,0,1,0,n,0,0,0,1,0);
            var newColorMatrix_filter:ColorMatrixFilter= new ColorMatrixFilter(newFilters);
            thumbs_array[e.currentTarget.id].filters=[newColorMatrix_filter];
        
            var dy:Number=60-masks_array[e.currentTarget.id].height;
            var ay:Number=dy*.2;
            masks_array[e.currentTarget.id].height+=ay;
            
            for(var i:Number=e.currentTarget.id+1;i<thumbs_array.length;i++)
            {
                thumbs_array[i].y+=ay/2;
                masks_array[i].y=thumbs_array[i].y+thumbs_array[i].height/2;
            }
            for(var j:Number=e.currentTarget.id-1;j>=0;j--)
            {
                thumbs_array[j].y-=ay/2;
                masks_array[j].y=thumbs_array[j].y+thumbs_array[j].height/2;
            }
            if(ay<=.1)
            {
                masks_array[e.currentTarget.id].height=60;
                e.currentTarget.removeEventListener(Event.ENTER_FRAME,liftUp);
            }
        }
        
        private function scaleDown(e:Event):void
        {
            var n:int=-50;
            var newFilters:Array=new Array(1,0,0,0,n,0,1,0,0,n,0,0,1,0,n,0,0,0,1,0);
            var newColorMatrix_filter:ColorMatrixFilter= new ColorMatrixFilter(newFilters);
            thumbs_array[e.currentTarget.id].filters=[newColorMatrix_filter];
            
            var dy:Number=30-masks_array[e.currentTarget.id].height;
            var ay:Number=dy*.2;
            masks_array[e.currentTarget.id].height+=ay;
            
            for(var i:Number=e.currentTarget.id+1;i<thumbs_array.length;i++)
            {
                thumbs_array[i].y+=ay/2;
                masks_array[i].y=thumbs_array[i].y+thumbs_array[i].height/2;
            }
            for(var j:Number=e.currentTarget.id-1;j>=0;j--)
            {
                thumbs_array[j].y-=ay/2;
                masks_array[j].y=thumbs_array[j].y+thumbs_array[j].height/2;
            }
            if(Math.abs(ay)<=.1)
            {
                masks_array[e.currentTarget.id].height=30;
                e.currentTarget.removeEventListener(Event.ENTER_FRAME,scaleDown);
                e.target.isPressed=false;
            }
        }
        
        private function showPicture(m:MouseEvent):void
        {
            checkOthers(m.currentTarget.id);
            m.currentTarget.isPressed=true;
            for(var i:int=0;i<pics_array.length;i++)
            {
                if(i==m.currentTarget.id)
                {
                    pics_array[i].visible=true;
                    TransitionManager.start(pics_array[i],{type:Photo,direction:Transition.IN,
                                            duration:1,easing:Regular.easeOut});
                }
                else
                {
                    TransitionManager.start(pics_array[currentPic],{type:Photo,direction:Transition.OUT,
                                            duration:1,easing:Regular.easeOut});
                }
            }
            currentPic=m.currentTarget.id;
        }
        
        private function checkOthers(n:int):void
        {
            for(var i:int=0;i<thumbs_array.length;i++)
            {
                if(i!=n)
                {
                    thumbs_array[i].isPressed=false;
                    closing(thumbs_array[i]);
                }
            }
        }
        
        // NON rimuovere per favore !
        public function initMenu():void
        {
            var etichetta:String='© FlepStudio.org';
            var cm:ContextMenu=new ContextMenu();
            var item:ContextMenuItem=new ContextMenuItem(etichetta);
            cm.hideBuiltInItems();
            cm.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT,itemHandler1);
            this.contextMenu=cm;
        }
        private function itemHandler1(event:ContextMenuEvent):void
        {
            var url:String='http://www.flepstudio.org/';
            var request:URLRequest=new URLRequest(url);
            navigateToURL(request,'_parent');
        }
    }
}

[Onsitus]

Grazie Flep,

il punto uno mi era importante vedro se posso fare cambiare idea. Sarebbe stato troppo facile riusare un script gia esistente.;)

Un altra cosa... che succede se mi serve riusare 3 volte stesso script? Creo 3 movieclip a quale associo 3 class dalla libreria, serve cambiare tutti nome var per non fare consusione tra di loro?bOh

Anche perche altro che le 3 mini galleria l'una vicina a l'altra, dovrano spostarsi per lasciare posto a l'imagine intera scelta.:D

[Flep]

Originally Posted by Onsitus

Grazie Flep,

il punto uno mi era importante vedro se posso fare cambiare idea. Sarebbe stato troppo facile riusare un script gia esistente.;)

Purtroppo per come è impostata la galleria bisogna ricreare il core, vedrò cosa posso fare :D

Un altra cosa... che succede se mi serve riusare 3 volte stesso script? Creo 3 movieclip a quale associo 3 class dalla libreria, serve cambiare tutti nome var per non fare consusione tra di loro?bOh

3 gallerie in una pagina html oppure 3 gallerie caricate in un file html ?

Anche perche altro che le 3 mini galleria l'una vicina a l'altra, dovrano spostarsi per lasciare posto a l'imagine intera scelta.:D

Questo mi fa pensare che voi usare 3 gallerie in un unico SWF.
Tutto da rifare, la Document Class del FLA lavora con un aray delle immagini e thumbs cha ci sono sullo stage.
Creare 3 gallerie significa rifare tutto, implementare una classe che lavora con 3 arrays diversi, implementargli dei metodi che se chiamati riposizionano i thumbs in base alla grandezza della foto scelta e in più 3 striscie di thumbs... alquanto complesso :o

[Onsitus]

Giusto 3 galleria in un swf, come in immagine1.
Poi le gallerie si devono spostare (cliccando il + in basso/destra o - per rinchiuderla) per avere il risultato di immagine2.

Quello sarebbe solo la parte del header e gia sono incasinata.:eek:

Cmq non preoccuparti credevo che con as sarebbe stato piu facile ma personalemente andro piu veloce a creare il tutto sulla timeline.:wall:

Non capisco perche ogni clip filmato non puo caricare la sua propria classe solo cambiando nome d'istanza/variabile/function per renderle ogni uno unico.:rolleyes:

Grazie per illuminarmi sulla facenda.;)

[Flep]

Originally Posted by Onsitus

Non capisco perche ogni clip filmato non puo caricare la sua propria classe solo cambiando nome d'istanza/variabile/function per renderle ogni uno unico.:rolleyes:

Non è così che funziona la galleria.
C'è una sola classe che gestisce le MovieClip delle immagini e delle thumbs.
Per creare 3 gallerie che lavorano come una sola e sono tute sincronizzate bisogna fare un lavoro accurato.
Un lavoro che potrebbe portare via un paio di giorni per farlo, non è semplice...

[Onsitus]

Ho capito Flep. Vedro come vanno le cose e se proprio non c'e la faccio d'un altra maniera e che il cliente la vuole proprio cosi, te lo faro sapere.;)

Nel fra tempo, gia so fino a quel punto si puo arrivare, prima di andare dire cavolate al cliente e ritrovarmi nella 'caca'.:)

Grazie.

[tem]

ciao Onsitus!
ho provato a fare un filmato con due gallery indipendenti..
sono partito però dalla gallery full screen di flep.. che si basa su file xml

sono riuscito a gestire 2 gallery "indipendenti" che si basano su 2 file xml distinti..

l'output grafico è molto diverso dal tuo e non vi sono gli effetti descritti(bianco nero,ingrandisci ); alle preview viene associata la stessa classe per lo spostamento.. bisognerebbe dargliene diverse con diverse aree d'azione...
cmq spero essere una base..

si può aggiungere anche una terza gallery..
i metodi e le proprietà che ho duplicato finiscono tutti con 2 es primaImmagine2()

copiando quelli ed aggiungendo 1 nuovo xml si può aggiungere anche la terza..

ecco il link:
www.thetconcept.com/flepstudio/Onsitusgal.zip

per guardarla:
main

tieni conto però che secondo me andrebbe usato un xml che comprenda tutto.. ma non so ancora gestirlo.. :)

spero cmq possa esserti un minimo d'aiuto..

a presto! :)

ps. grazie delle dritte su Masterdrive! (san_salvario)

[Onsitus]

Hey, non sapevo che eri te. Mi fa piacere saperti qui.;)
Adesso sono confusa e non sapro piu come chiamarti.:D

Ho scaricato il zip, grazie mille. Puo essere che mi sara d'aiuto visto che non ho ancora deciso come andare avanti.bOh

Al momento mi sono fermata sul provare a spostare le gallerie (al momento uso solo un quadretto colorato mascherato) cosi che quando una di loro viene scelta, si ridimensiona, prende tutto il spazio disponibile e spinge le altre fuori da vista. La mia prima bataglia contro l'uso dei classe. Poi vedro di cambiare ogni quadretto con le gallerie.:o

Mi capisco da sola.:D

[tem]

eh eh! in bocca al lupo!:)

cmq adesso che inizio a cominciare a capire un pò di più.. sono finalmente convinto che il passaggio,,, valga la fatica iniziale,,,,,

a presto!;)