E il banner Merry Xmas di Flep ?

[valesan]

So che sto chiedendo troppo, ma è possibile avere un aiuto
per la creazione di un banner natalizio tipo quello in alto dove flepstudio
augura buon natale ?? ;)

anche solo sapere come fare l'effetto nevicata ...

[Flep]

Ciao

L' effetto che uso io è dato da questo codice:

- dalla timeline istanzio la classe Snow, in questo modo:

var timer:Timer=new Timer(100,0);
timer.addEventListener(TimerEvent.TIMER,flake);
timer.start();

function flake(evt:TimerEvent):void
{
	var f:Snow=new Snow();
	addChild(f);
}

- la classe Snow ( associata ad una MovieClip in libreria )

package
{
	import flash.display.MovieClip;
	import flash.events.Event;
	
	public class Snow extends MovieClip
	{
		private var vx:Number;
		private var vy:Number;
		private var center:Number;
		private var spring:Number=.1;
		private var angle:Number=0;
		
		public function Snow()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(evt:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,init);
			x=Math.random()*stage.stageWidth;
			y=-height;
			scaleX=scaleY=0.2+Math.random()*1;
			vy=scaleX*6;
			vx=vy;
			center=x;
			addEventListener(Event.ENTER_FRAME,go);
		}
		
		private function go(evt:Event):void
		{
			var acc_x:Number=(center-x)*spring;
			vx+=acc_x;
			x+=vx;
			//alpha-=.005;
			var sine:Number=Math.sin(this.angle);
			scaleX=sine;
			angle+=.2;
			
			y+=vy;
			if(y>=stage.stageHeight+height)
			{
				removeEventListener(Event.ENTER_FRAME,go);
				var my_parent:MovieClip=parent as MovieClip;
				my_parent.removeChild(this);
			}
		}
	}
}

Puoi scaricare i files da quì:
http://www.flepstudio.org/sharing/HeaderForum.zip

Oppure hai anche un altro bello esempio che ha creato un utente di FlepStudio, lo trovi quì:
http://www.flepstudio.org/forum/util...flash-cs3.html

[valesan]

Mitico ...

oltre che professionale e supergentile sei anche velocissimo !!!

un grazie di cuore e buon Natale ;)

[Flep]

Buon Natale anche a te !

Ho appena trovato anche queste icone se a qualcuno possono interessare:
Adobe CS3 Icons - xMas style by ~iixo on deviantART