website loading external swfs

[jimbo]

Okay, I'm learning your example, and have a problem. In your example, you have a first button that loads the home page - I tried to remove all references to this, and have the home page load from the init function, but have failed - carciaHome gives me:
Cannot access a property or method of a null object reference.

I am still struggling to understand what is happening . . . is it necessary to have the opening button for this kind of site to work? Can the main.swf become the home page, or load the home page without any button push?

[Flep]

It's simple,
into init() function comment the line:

//aggiungiListenerEntra();

and add:

entra();

also, comment the function

/*private function aggiungiListenerEntra():void
{
	logo_mc.entra_mc.buttonMode=true;
	logo_mc.entra_mc.addEventListener(MouseEvent.MOUSE_DOWN,entra);
}*/

last, the entra() function becomes:

private function entra():void
{
	//this.gotoAndStop(2);
	caricaHome();
}

[jimbo]

Okay,
I tried almost that - I commented out what you said, plus the entra fuction - then put the entra statements in the init function, and it didn't work.

Now, I did as you say, and the compiler tells me that entra(); needs 1 argument?

[Flep]

Yes, you must delete the argument.
Watch the new entra() i wrote:

private function entra():void
{
	//this.gotoAndStop(2);
	caricaHome();
}

[jimbo]

Ahhh, my bad. I did not notice that you removed the mouse event from entra(); - my old eyes are not working too good :)

[jimbo]

hmmm, now I get the similar error as when I removed all entra references and moved caricaHome(); up to init function:

TypeError: Error #1009: Cannot access a property or method of a null object reference.
at Main/::caricaHome()
at Main/::entra()
at Main/::init()
at Main$iinit()

[Flep]

Sorry dude, or us mediterranean people it's too late i'm going to sleep.

Here is the entire class i've modified:

/*
 ********************************
 * http://www.FlepStudio.org    *
 * @ Author: Filippo Lughi      *
 ********************************
 */
package
{
	import flash.display.MovieClip;
	import flash.display.SimpleButton;
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.*;
	
	public class Main extends MovieClip
	{
		private var sezioni_array:Array;
		private var bottoni_sezioni_array:Array;
		
		private var loader:Loader;
		
		private var swf:String;
		
		private var id:int=0;
		
		public function Main()
		{
			init();
		}
		
		private function init():void
		{
			stop();
			stage.frameRate=31;
			
			home_btn.visible=false;
			menu_mc.visible=false;
			preloader_mc.visible=false;
			preloader_mc.fill_mc.width=0;
			
			sezioni_array=new Array('sezioni/home.swf',
			'sezioni/sezione1.swf',
			'sezioni/sezione2.swf',
			'sezioni/sezione3.swf',
			'sezioni/sezione4.swf',
			'sezioni/sezione5.swf');
			bottoni_sezioni_array=new Array(menu_mc.sezione_1_mc,menu_mc.sezione_2_mc,
			menu_mc.sezione_3_mc,menu_mc.sezione_4_mc,
			menu_mc.sezione_5_mc);
			
			//aggiungiListenerEntra();
			aggiungiListenerTornaHome();
			aggiungiListenerMenu();
			entra();
		}
		
		/*private function aggiungiListenerEntra():void
		{
			logo_mc.entra_mc.buttonMode=true;
			logo_mc.entra_mc.addEventListener(MouseEvent.MOUSE_DOWN,entra);
		}*/
		
		private function aggiungiListenerTornaHome():void
		{
			home_btn.addEventListener(MouseEvent.MOUSE_DOWN,tornaHome);
		}
		
		private function aggiungiListenerMenu():void
		{
			for(var i:int=0;i < bottoni_sezioni_array.length;i++)
			{
				bottoni_sezioni_array[i].id=i;
				bottoni_sezioni_array[i].addEventListener(MouseEvent.MOUSE_DOWN,moveNestedClip);
			}
		}
		
		private function entra():void
		{
			//this.gotoAndStop(2);
			caricaHome();
		}
		
		private function tornaHome(m:MouseEvent):void
		{
			id=0;
			loader.unload();
			removeChild(loader);
			rimuoviListeners(loader.contentLoaderInfo);
			caricaHome();
		}
		
		private function caricaHome():void
		{
			swf=sezioni_array[0];
			var request:URLRequest=new URLRequest(swf);
			loader=new Loader();
			initListeners(loader.contentLoaderInfo);
			loader.load(request);
			id=0;
		}
		
		private function moveNestedClip(m:MouseEvent):void
		{
			var loadedSWF:MovieClip=loader.content as MovieClip;
			var nested_clip:MovieClip=loadedSWF.benvenuti_mc as MovieClip;
			nested_clip.gotoAndPlay(32);
			nested_clip.addEventListener(Event.ENTER_FRAME,moveMyTimeLine);
			function moveMyTimeLine(evt:Event):void
			{
				if(evt.currentTarget.currentFrame==62)
				{
					evt.currentTarget.stop();
					evt.currentTarget.removeEventListener(Event.ENTER_FRAME,moveMyTimeLine);
					cambiaSezione(m);
				}
			}
		}
		
		private function cambiaSezione(m:MouseEvent):void
		{
			id=m.target.parent.id+1;
			loader.unload();
			removeChild(loader);
			rimuoviListeners(loader.contentLoaderInfo);
			caricaSezione(m.target.parent.id+1);
		}
		
		private function caricaSezione(n:int):void
		{
			swf=sezioni_array[id];
			var request:URLRequest=new URLRequest(swf);
			loader=new Loader();
			initListeners(loader.contentLoaderInfo);
			loader.load(request);
		}
		
		private function initListeners(dispatcher:IEventDispatcher):void 
		{
			dispatcher.addEventListener(Event.OPEN,inizia);
			dispatcher.addEventListener(ProgressEvent.PROGRESS,inCaricamento);
			dispatcher.addEventListener(Event.COMPLETE,completato);
		}
		
		private function rimuoviListeners(dispatcher:IEventDispatcher):void 
		{
			dispatcher.removeEventListener(Event.OPEN,inizia);
			dispatcher.removeEventListener(ProgressEvent.PROGRESS,inCaricamento);
			dispatcher.removeEventListener(Event.COMPLETE,completato);
		}
		
		private function inizia(event:Event):void 
		{
			menu_mc.visible=false;
			preloader_mc.visible=true;
		}
		private function inCaricamento(event:ProgressEvent):void 
		{
			var n:uint=(event.bytesLoaded/event.bytesTotal)*100;
			preloader_mc.fill_mc.width=n;
		}
		private function completato(event:Event):void 
		{
			addChild(loader);
			swappa();
			preloader_mc.visible=false;
			if(id!=0)
				home_btn.visible=true;
			else
				home_btn.visible=false;
			menu_mc.visible=true;
		}
		
		private function swappa():void
		{
			swapChildren(loader,menu_mc);
			swapChildren(home_btn,loader);
		}
	}
}

[jimbo]

Your version works, I will study what I did wrong. I am sorry to keep you awake. Sweet dreams.