Modifying external swf site of Flep

[madmad]

Hy Flep,

i´m trying to modify your great flash cs3 site! but i´m a bit stuck, so maybe you could help:

package
{
    import flash.display.MovieClip;
    import flash.display.SimpleButton;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.*;
    
    public class Main extends MovieClip
    {
        private var section_array:Array;
        private var button_section_array:Array;
        
        private var loader:Loader;
        
        private var swf:String;
        
        private var id:int=0;
        
        public function Main()
        {
            init();
        }
        
        private function init():void
        {
            stop();
            stage.frameRate=31;
            
            home_btn.visible=false;
            menu_mc.visible=false;
            preloader_mc.visible=false;
            preloader_mc.fill_mc.width=0;
            
            section_array=new Array('./home/home.swf',
            './ouverture/ouverture.swf',
            './klassik/klassik.swf',
            './stoff1/stoff1.swf',
            './stoff2/stoff2.swf',
            './kleider/kleider.swf');
            button_section_array=new Array(menu_mc.sezione_1_mc,menu_mc.sezione_2_mc,
            menu_mc.sezione_3_mc,menu_mc.sezione_4_mc,
            menu_mc.sezione_5_mc);
            
            addListenerEnter();
            addListenerHome();
            addListenerMenu();
        }
        
        private function addListenerEnter():void
        {
            logo_mc.entra_mc.buttonMode=true;
            logo_mc.entra_mc.addEventListener(MouseEvent.MOUSE_DOWN,entra);
        }
        
        private function addListenerHome():void
        {
            home_btn.addEventListener(MouseEvent.MOUSE_DOWN,tornaHome);
        }
        
        private function addListenerMenu():void
        {
            for(var i:int=0;i < button_section_array.length;i++)
            {
                button_section_array[i].id=i;
                button_section_array[i].addEventListener(MouseEvent.MOUSE_DOWN,cambiaSezione);
            }
        }
        
        private function entra(m:MouseEvent):void
        {
            this.gotoAndStop(2);
            caricaHome();
        }
        
        private function tornaHome(m:MouseEvent):void
        {
            id=0;
            loader.unload();
            removeChild(loader);
            rimuoviListeners(loader.contentLoaderInfo);
            caricaHome();
        }
        
        private function caricaHome():void
        {
            swf=section_array[0];
            var request:URLRequest=new URLRequest(swf);
            loader=new Loader();
            initListeners(loader.contentLoaderInfo);
            loader.load(request);
            id=0;
        }
        
        private function cambiaSezione(m:MouseEvent):void
        {
            id=m.target.parent.id+1;
            loader.unload();
            removeChild(loader);
            rimuoviListeners(loader.contentLoaderInfo);
            caricaSezione(m.target.parent.id+1);
        }
        
        private function caricaSezione(n:int):void
        {
            swf=section_array[id];
            var request:URLRequest=new URLRequest(swf);
            loader=new Loader();
            initListeners(loader.contentLoaderInfo);
            loader.load(request);
        }
        
        private function initListeners(dispatcher:IEventDispatcher):void 
        {
            dispatcher.addEventListener(Event.OPEN,inizia);
            dispatcher.addEventListener(ProgressEvent.PROGRESS,inCaricamento);
            dispatcher.addEventListener(Event.COMPLETE,completato);
        }
        
        private function rimuoviListeners(dispatcher:IEventDispatcher):void 
        {
            dispatcher.removeEventListener(Event.OPEN,inizia);
            dispatcher.removeEventListener(ProgressEvent.PROGRESS,inCaricamento);
            dispatcher.removeEventListener(Event.COMPLETE,completato);
        }
        
        private function inizia(event:Event):void 
        {
            menu_mc.visible=false;
            preloader_mc.visible=true;
        }
        private function inCaricamento(event:ProgressEvent):void 
        {
            var n:uint=(event.bytesLoaded/event.bytesTotal)*100;
            preloader_mc.fill_mc.width=n;
        }
        private function completato(event:Event):void 
        {
            addChild(loader);
            swappa();
            preloader_mc.visible=false;
            if(id!=0)
                home_btn.visible=true;
            else
                home_btn.visible=false;
            menu_mc.visible=true;
        }
        
        private function swappa():void
        {
            swapChildren(loader,menu_mc);
            swapChildren(home_btn,loader);
        }
    }
}

Instead of a simple button i want to have my own buttons, with something like "over" "out" and "active" or just gotoAndStop(1) / (2) / (3).

And i want to get rid of the home button thing (i want to integrate in one of these buttons, but of course should be loaded first!

Would be cool to get some respond, b´cause your tutorial is the only one over the net i really think that works!

mucho gracie
Madmad