Actionscript 3 bitmap e bitmapData

[Inghe]

Ciao a tutti, ho il seguente problema spero che mi possiate aiutare in qualche modo :)

Sto creando come esercizio una galleria photo dinamica che prende le immagini da un file xml.
Mi ero posto come obbiettivo di non usare i Thumb delle immagini ma caricare direttamente le immagini originali, inserendole in un array, per poi visualizzarle ridimensionate nella parte bassa dello stage e poi una volta cliccatoci sopra visualizzate a grandezza reale nella parte alta dello stage.
Fin qui tutto ok, riesco a fare tutto, l'unica cosa è che quando clicco sul "finto" thumb dell'immagine questo mi sparisce, ma mi visualizza l'immagine grande dove voglio io!!

Ho ipotizzato (da "principiante") che il problema poteva essere che le immagini sono oggetti di tipo bitmap e che quindi vengono rimpiazzate al posto che aggiunte.
Cercando su internet ho trovato il metodo clone() della classe bitmapdata che mi permette di clonare un oggetto bitmapdata, ma nel mio caso ho un bitmap..come posso fare? è questo secondo voi il problema?

grazie in anticipo

[Silver55]

ciao,
puoi creare una nuova bitMap con la stessa bitMapData, in questo caso avrai due immagini diverse che fanno riferimanto alla stessa bitMapData, oppure puoi clonare la bitMapdata ( nel caso hai la necessità di aggiungere effetti diversi alle bitmapdata )

// .............................................................................. 
//  FUNCTION : onCompleteImage() 
//             COMPLETATO CARICAMENTO IMMAGINE 
// .............................................................................. 
function onCompleteImage(evt:Event):void 
{
    var tempLoader :Loader;
    var ImgBitMap :Bitmap;
    var ImgBitMapData :BitmapData;
    var newBitMap :Bitmap;
    var newBitMapData :BitmapData;
 
    // ... ACQUISIZIONE IMMAGINE CARICATA 
    tempLoader = Loader(evt.target.loader);
 
    // ... ACQUISIZIONE DELLA BITMAP 
    ImgBitMap = Bitmap(tempLoader.content);
 
    // ... ACQUISIZIONE DELLA RELATIVA BITMAPDATA 
    ImgBitMapData = ImgBitMap.bitmapData;
 
    // ... 
    tempLoader.x = 10; 
    tempLoader.y = 10; 
    tempLoader.width = 202; 
    tempLoader.height = 187; 
 
    addChild(tempLoader); 
    // ... 
 
    // ... 1. - CREA UNA NUOVA BITMAP CON LA STESSA BITMAPDATA 
    newBitMap = new Bitmap(ImgBitMapData);
 
    // ... IN QUESTO CASO AVRO' DUE IMMAGINI DIVERSE MA CON LA STESSA BITMAPDATA 
    // ... EFFETTI SULLA BITMAPDATA, SI OTTENGONO SU ENTRAMBE LE IMMAGINI 
 
    // ... es. : 
    // ImgBitMapData.noise(5, 0, 0xFF, BitmapDataChannel.RED, false);
    // ... etc ... 
 
 
    // ... 2. OPPURE SI PUO' CLONARE LA BITMAPDATA
    //        ( SE HO NECESSITA' DI APPLICARE EFFETTI DIVERSI SULLE BITMAPDATA ) 
 
    // ... CLONAZIONE DELLA BITMAPDATA  
    // newBitMapData = ImgBitMapData.clone();
 
    // newBitMap = new Bitmap(newBitMapData);
    // newBitMapData.noise(5, 0, 0xFF, BitmapDataChannel.RED, true);
 
    // ... NEW BITMAP 
    newBitMap.x = 220; 
    newBitMap.y = 10; 
    newBitMap.width = 202/2; 
    newBitMap.height = 187/2; 
 
    addChild(newBitMap); 
    // ... 
} 
// ..............................................................................

[Inghe]

Perfetto...ho provato ed ho risolto quindi era proprio quello il problema: acquisisco le bitmap attraverso il loader, poi però se voglio riutilizzare la stessa bitmap all'interno dello stage senza che questa venga sostituita devo clonarla ma non riuscivo a passare dall'oggetto bitmap all'oggetto bitmapData per poterlo clonare, ma con il metodo miaBitmap.bitmapData ho risolto
GRAZIE DAVVERO ieri sono stato ad impazzire sopratutto per capire quale fosse l'origine del problema :D:D:D