Caricamento swf

[Marco756]

Ho provato questo codice sul primo keyframe:

// inizializzo una variabile di tipo stringa che contenga il nome del file da caricare
var filename:String = "my_swf.swf";
// inizializzo una richiesta url esterna, tramite la classe URLRequest e gli passo il nome del file da caricare
var request:URLRequest = new URLRequest(filename);
// inizializzo un'istanza del DisplayObjectContainer, di tipo Loader()
var loader:Loader = new Loader();
// inizializzo un'istanza di LoaderInfo per assegnargli i listener corrispondenti alle azioni
var infoloader:LoaderInfo = loader.contentLoaderInfo;
// aggancio le azioni ad ogni evento per monitorare il caricamento
infoloader.addEventListener(Event.COMPLETE, completeHandler);
infoloader.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
infoloader.addEventListener(Event.INIT, initHandler);
infoloader.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
infoloader.addEventListener(Event.OPEN, openHandler);
infoloader.addEventListener(ProgressEvent.PROGRESS, progressHandler);

// inizializzo le funzioni corrispondenti agli eventi da verificare per la classe Loader
function completeHandler(event:Event) {
    trace("Caricamento completato, è possibile effettuare azioni sul file appena caricato!");
}
function httpStatusHandler(event:HTTPStatusEvent) {
    trace("Ricevuto stato http "+event.status);
}
function initHandler(event:Event) {
    trace("File esterno inizializzato, è adesso possibile richiamare le azioni contenute nel file esterno!");
}
function ioErrorHandler(event:IOErrorEvent) {
    trace("Errore durante il caricamento del file");
}
function openHandler(event:Event) {
    trace("Caricamento inizializzato, attendere il completamento!");
}
function progressHandler(event:ProgressEvent) {
    var percentual:int = (event.bytesLoaded/event.bytesTotal)*100;
    trace("Caricamento di "+percentual+"%");
}

// richiamo il metodo Loader.load(request:URLRequest), per iniziare il caricamento esterno
// e gli passo come parametro, la richiesta url inizializzata in precedenza
loader.load(request);
// inserisco il Loader() nella "display list" dello stage corrente
addChild(loader);

Il problema è che con alcuni filmati mi carica tutto regolarmente, con altri mi esce un errore di output che dice:

Caricamento inizializzato, attendere il completamento!
Caricamento di 0%
Caricamento di 100%
TypeError: Error #1009: Impossibile accedere a una proprietà o a un metodo di un riferimento oggetto null.
    at Main/::init()
    at Main$iinit()

[Flep]

Ciao

addChild(loader);

va messo dentro la funzione completeHandler _:mad:

[Marco756]

Ciao ,
scusami ma non ho ancora risolto il problema.
Il fatto è che mi da sempre il solito errore (alcuni swf non li carica).
Ti allego il file "test_caricamento.fla" dove cerco di caricare uno dei tuoi file (si tratta del game).
Grazie.

[Flep]

Il problema è che non usi l' evento Event.ADDED_TO_STAGE .

Guarda questo tutorial:
http://www.flepstudio.org/forum/acti...ent-class.html

Quindi, la prima parte di Main.as diventa così:

public function Main()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
		
		private function init(evt:Event):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,init);
			stage.frameRate=31;
			
			gallina_mc.x=stage.stageWidth/2;
			gallina_mc.y=gallina_mc.height+10;
			
			cambio=1000+Math.floor(Math.random()*6000);
			
			cambia_livello_mc.visible=false;
			game_over_mc.visible=false;
			punteggio_txt.text='punteggio: '+punteggio;
			
			attivaTimer();
			listeners();
			lanciaUova();
		}

Adesso funziona.

[Marco756]

Ok funziona tutto. Grazie
Però non capisco perchè la gallina esce dal suo stage originale ......anzi addirittura esce dallo stage del nuovo swf!!!!!!!!!!